CraftScript

mod "rubies" { name: "Rubies", version: "1.0.0", author: "you" }

// What exists
import "content/items"
import "content/ores"
import "content/world"
import "content/dimensions"
import "content/creatures"
import "content/sounds"
import "content/particles"
import "content/recipes"

// What happens
import "events/mining"
import "events/hunting"
import "events/welcome"
import "commands/realm"
import "commands/rubies"
import "commands/shop"

let coins = 100
const MAX_HOMES = 3                          // const：再代入できない
let greeting = "コインを {coins * 2} 枚持っています"
let names = ["Ana", "Ben"]
let prices = { gold: 5, ruby: 2 }

names.add("Cleo")
prices["diamond"] = 9
log(len(names), prices.gold, prices.keys())

fun describe(coins: number, banned: bool): string {
    if coins > 100 and not banned {
        return "裕福"
    } else if coins == 0 {
        return "無一文"
    }
    return "普通"
}

fun countdown() {
    for i in 1..5 { broadcast("{6 - i}…") }    // 両端を含む範囲
    for p in players() { p.send("スタート！") }
}

fun who(target: Player?, fallback: Player): string {
    let p = target ?? fallback                  // ?? ：null のときの値
    return p?.name ?? "誰もいない"              // ?. ：null でも安全
}

fun give_rubies(p: Player, amount: number = 1) {
    p.give(item("rubies:ruby", amount))
}

fun healthy(): list<Player> {
    return players().filter(fun(p) { return p.health > 10 })
}

const BLOCKED = ["spam", "scam"]

on chat(e) priority high {
    if BLOCKED.any(fun(w) { return e.message.contains(w) }) {
        e.cancel()
        e.player.send("&c仲良くしましょう")
    }
}

command heal(target: player?, amount: number?) requires "rubies.heal" alias "h" describe "プレイヤーを回復する" {
    let p = target ?? player
    if p == null { return "プレイヤーを指定してください" }
    p.health = min(p.max_health, p.health + (amount ?? 20))
    return "{p.name} を回復しました"
}

every 5 minutes { broadcast("&6投票をお忘れなく") }

after 10 seconds { log("サーバーが起動して 10 秒経ちました") }

on join {
    player.helth = 20          // タイプミス
    player.name = "Admin"      // 読み取り専用のプロパティ
    player.give()              // 引数が足りない
}

welcome.craft:2: error: Player has no property 'helth'. Did you mean 'health'?
welcome.craft:3: error: Player.name is read-only
welcome.craft:4: error: give() expects 1 argument(s), got 0

fun heal(p: Player, amount: number = 20): bool {
    p.health = min(p.max_health, p.health + amount)
    return true
}

// heal(player, "a lot")  →  error: Argument 'amount' of heal() must be number, got string

command home(target: player?) {
    if target == null { return "プレイヤーを指定してください" }
    target.teleport(world().block_at(0, 80, 0).location)   // ここでは target はもう null ではない
}

class Wallet {
    coins: number = 100

    fun pay(n: number): bool {
        if n > this.coins { return false }
        this.coins -= n
        return true
    }
}

class VipWallet extends Wallet {
    fun pay(n: number): bool {
        return super.pay(n / 2)      // VIP は半額
    }
}

enum Rank { PEASANT, KNIGHT, LORD, KING }

fun rank_for(coins: number): Rank {
    if coins >= 1000 { return Rank.LORD }
    return Rank.PEASANT
}

// Rank.LORD.name → "LORD", Rank.values() → [PEASANT, …], Rank.from("king") → KING

import { VipWallet } from "/lib/wallet"
import { rank_for } from "/lib/rank"

let wallets = {}

on join {
    wallets[player.name] = VipWallet()
    player.send("ランク：{rank_for(wallets[player.name].coins).name}")
}