CraftScript

mod "rubies" { name: "Rubies", version: "1.0.0", author: "you" }

// What exists
import "content/items"
import "content/ores"
import "content/world"
import "content/dimensions"
import "content/creatures"
import "content/sounds"
import "content/particles"
import "content/recipes"

// What happens
import "events/mining"
import "events/hunting"
import "events/welcome"
import "commands/realm"
import "commands/rubies"
import "commands/shop"

let coins = 100
const MAX_HOMES = 3                          // const : ne peut pas être réaffectée
let greeting = "Tu as {coins * 2} pièces"
let names = ["Ana", "Ben"]
let prices = { gold: 5, ruby: 2 }

names.add("Cleo")
prices["diamond"] = 9
log(len(names), prices.gold, prices.keys())

fun describe(coins: number, banned: bool): string {
    if coins > 100 and not banned {
        return "rich"
    } else if coins == 0 {
        return "broke"
    }
    return "fine"
}

fun countdown() {
    for i in 1..5 { broadcast("{6 - i}…") }    // intervalle inclusif
    for p in players() { p.send("C’est parti !") }
}

fun who(target: Player?, fallback: Player): string {
    let p = target ?? fallback                  // ?? : valeur si null
    return p?.name ?? "personne"                // ?. : sûr si null
}

fun give_rubies(p: Player, amount: number = 1) {
    p.give(item("rubies:ruby", amount))
}

fun healthy(): list<Player> {
    return players().filter(fun(p) { return p.health > 10 })
}

const BLOCKED = ["spam", "scam"]

on chat(e) priority high {
    if BLOCKED.any(fun(w) { return e.message.contains(w) }) {
        e.cancel()
        e.player.send("&cReste aimable, s’il te plaît")
    }
}

command heal(target: player?, amount: number?) requires "rubies.heal" alias "h" describe "Soigne un joueur" {
    let p = target ?? player
    if p == null { return "Indique un joueur" }
    p.health = min(p.max_health, p.health + (amount ?? 20))
    return "{p.name} a été soigné"
}

every 5 minutes { broadcast("&6N’oublie pas de voter") }

after 10 seconds { log("le serveur tourne depuis 10 secondes") }

on join {
    player.helth = 20          // faute de frappe
    player.name = "Admin"      // propriété en lecture seule
    player.give()              // argument manquant
}

welcome.craft:2: error: Player has no property 'helth'. Did you mean 'health'?
welcome.craft:3: error: Player.name is read-only
welcome.craft:4: error: give() expects 1 argument(s), got 0

fun heal(p: Player, amount: number = 20): bool {
    p.health = min(p.max_health, p.health + amount)
    return true
}

// heal(player, "beaucoup")  →  error: Argument 'amount' of heal() must be number, got string

command home(target: player?) {
    if target == null { return "Indique un joueur" }
    target.teleport(world().block_at(0, 80, 0).location)   // ici, target n’est plus null
}

class Wallet {
    coins: number = 100

    fun pay(n: number): bool {
        if n > this.coins { return false }
        this.coins -= n
        return true
    }
}

class VipWallet extends Wallet {
    fun pay(n: number): bool {
        return super.pay(n / 2)      // les VIP paient moitié prix
    }
}

enum Rank { PEASANT, KNIGHT, LORD, KING }

fun rank_for(coins: number): Rank {
    if coins >= 1000 { return Rank.LORD }
    return Rank.PEASANT
}

// Rank.LORD.name → "LORD", Rank.values() → [PEASANT, …], Rank.from("king") → KING

import { VipWallet } from "/lib/wallet"
import { rank_for } from "/lib/rank"

let wallets = {}

on join {
    wallets[player.name] = VipWallet()
    player.send("Rang : {rank_for(wallets[player.name].coins).name}")
}